How to avoid proc sql in SAS - sas

Question

I have a panel dataset at hourly frequency. I want to delete all observations if there are less than 200 observation at any given one hour interval. So I first count the number of observations N at each hour, then delete if N < 200. However, the proc sql common in step 2 use up all my C disk free space. Is there a better way to achieve my target?
data lib.data;
set lib.data;
retain I; by date hour;
if first.date or first.hour then I=1; else I=I+1;
run;
proc sql;
create table lib.data1
as select a.*, max(I) as N
from lib.data as a
group by date, hour
order by date, hour;
quit;
data lib.data (drop= i n);
set lib.data;
if n < 200 then delete;
run;

Answer 1

Use a double DOW loop. The first one will count the number of records. Then the second one can use that count to conditionally execute an OUTPUT statement.
data want ;
do until (last.hour);
set lib.data;
by date hour;
n=sum(n,1);
end;
do until (last.hour);
set lib.data;
by date hour;
if n >= 200 then output;
end;
run;

Answer 2

PROC SQL in itself is not the problem. It's the unintended consequences (such as remerging of data) of not having all of your non-summary columns in the GROUP BY. Here's a SQL solution that hopefully shouldn't blow up your drive.
proc sql;
create table want as
select
a.*
from
lib.data a
join
(select
date,
hour,
count(*)
from
lib.data
group by date, hour
having count(*) >= 200) b
on
a.date = b.date and
a.hour = b.hour
;
quit;

Answer 3

You could try to use hash table to store first 200 records. And when you reach 200th record output data from hash table and the rest observations from current hour.
The code below shows how it could works:
data lib.data (drop= counter rc);
set lib.data;
by date hour;
retain counter 0;
If _N_ =1 then do;
declare hash hs(multidata:'yes');
hs.definekey('date','hour');
hs.definedone();
end;
/*if first record in hour zero counter*/
if first.hour then do;
counter=0;
end;
/*increment counter*/
counter = counter+1;
/*if counter less then 200 add record to hash table*/
if counter < 200 then do;
hs.add();
end;
/*if counter=200 output current record and record from hash*/
if counter = 200 then do;
output;
rc = hs.find();
do while(rc=0);
output;
rc= hs.find_next();
end;
end;
/*if counter greater then 200 output current record*/
if counter > 200 then output;
/*if last record in hour clear hash*/
if last.hour then do;
hs.clear();
end;
run;