Stata portable code with mkdir - if-statement

Question

So, I'm trying to write a line of that will check if there is a directory present, and only try and create a directory if that is false. Found this on Statalist:
local name test_directory
cd C:\
capture confirm file "./`name'/nul" // check if `name' subdir exists
if _rc { // _rc will be >0 if it doesn't exist
!md "`name'"
}
// my do file
save "C:/`name'/current_data.dta" // optionally add -,replace-
Looks pretty solid overall for my application, but I'm struggling with converting it to Mac compatible syntax.
local name test_directory
cd ~/
capture confirm file "./`name'/*"
// check if `name' subdir exists
if _rc {
mkdir "`name'"
}
Any advice on how to do this right?

Answer 1

You can try relying on the return code of the cd command. This is the approach taken by confirmdir (from SSC):
local somedir /home/roberto/Desktop/test
quietly capture cd `"`somedir'"'
if (_rc) display as text "return code `=_rc'; do something, like mkdir"
else display as text "could change dir; the dir exists"
This will signal if
cd was unable to change to the directory you typed because either it
does not exist, it is protected, or it is not a directory
Source: search r(170).
If you plan on issuing several commands after the conditionals, then you need the if {...} else {...} syntax. See help ifcmd.
If you don't want to end up in a different directory, you can save the current one at the beginning
local cwd `"`c(pwd)'"'
and switch back to it when your done:
quietly cd `"`cwd'"'
It should work on both MS Windows and Unix-type OS. (But I can't test on MS Windows.)

Answer 2

I usually use the shell for things like this:
local name test_directory
cd ~
!if test -d `name'; then echo "`name' Already Exists"; else mkdir `name'; fi
I don't really understand why your second code fails.

Answer 3

The problem is the asterisk at the end of the capture statement: if test_directory exists but is empty, nothing will match and _rc will be nonzero. Maybe you meant the asterisk to be a "."?
But the slash before that character is also a problem: if a plain file exists named test_directory, the confirm will fail because "test_directory/." does not exist but mkdir will also fail because of the name conflict.
The following works for me, Stata 13.1 on OS X 10.10, with a little extra output for debugging to confirm what path I've taken.
local name test_directory
cd "~/Research/Stata sandbox"
capture confirm file "./`name'"
// check if `name' subdir exists
if _rc {
mkdir "`name'"
display "`name' created"
}
else {
display "`name' already exists"
}

Answer 4

The following works on all platforms
local dir_to_use "whatever_dir_name"
capture mkdir "`dir_to_use'"
Nothing bad will happen if the directory already exists.

Answer 5

Some may find this simple solution for a do-file handy:
local name test_directory
capture mkdir "C:/`name'/"
save "C:/`name'/current_data.dta"
This will make a folder with the name test_directory if this folder is not already present. The code also runs without error if the folder already existed.