I changed repetitive awk expressions into one function - regex

Question

I had a 8 awk expressions that only differed by 2 patterns I was searching for. So I then created an awk function to improve my code, however now it wont work. What I am doing is...
printFmt () {
awk -v MYPATH="$MYPATH" -v FILE_EXT="$FILE_EXT" -v NAME_OF_FILE="$NAME_OF_FILE" -v DATE="$DATE" -v PATTERN="$1" -v SEARCH="$2" '
$0 ~ PATTERN {
rec = $1 OFS $2 OFS $4 OFS $7
for (i=9; i<=NF; i++) {
rec = rec OFS $i
if ($i ~ SEARCH) {
break
}
}
print rec >> "'$MYPATH''$NAME_OF_FILE''$DATE'.'$FILE_EXT'"
}
' "$FILE_LOCATION"
}
and calling with printFmt "$STORED_PROCS_FINISHED" "/([01])/". My code was exactly above except instead of SEARCH it was /([01])/. Is there something with syntax that i am missing?

Answer 1

Do this and read the book Effective Awk Programming, 4th Edition, by Arnold Robbins:
printFmt () {
awk -v regexp1="$1" -v regexp2="$2" '
$0 ~ regexp1 {
rec = $1 OFS $2 OFS $4 OFS $7
for (i=9; i<=NF; i++) {
rec = rec OFS $i
if ($i ~ regexp2) {
break
}
}
print rec
}
' "$FILE_LOCATION" >> "${MYPATH}${NAME_OF_FILE}${DATE}.${FILE_EXT}"
}
printFmt "$STORED_PROCS_FINISHED" "[01]"
Your use of all-caps for variable names is bad - that's for exported shell variables only.
Don't use the word "pattern" as it's ambiguous, and "search" is meaningless - come up with 2 meaningful names for the variables that I named regexp1 and regexp2.

Answer 2

As noted in comments:
You should omit the slashes from the regex passed as a parameter. Passing "([01])" instead of "/([01])/" should work correctly. I'm not convinced the parentheses are necessary either; just "[01]" should work too.
You pass values with -v to the awk script that are not used inside the awk script. You have the shell use those values to create a file name as well. You should either not pass the values to awk, or you should not use the shell to create the file name.
Given these comments, I think your code could be:
printFmt() {
awk -v PATTERN="$1" -v SEARCH="$2" '
$0 ~ PATTERN {
rec = $1 OFS $2 OFS $4 OFS $7
for (i=9; i<=NF; i++) {
rec = rec OFS $i
if ($i ~ SEARCH) {
break
}
}
print rec
}
' "$FILE_LOCATION" >> "$MYPATH$NAME_OF_FILE$DATE.$FILE_EXT"
}
printFmt "$STORED_PROCS_FINISHED" "[01]"
Unless the constructed file name changes on each invocation of the function, I would create the file name once, outside the function, and use it outside the function:
printFmt() {
awk -v PATTERN="$1" -v SEARCH="$2" '
$0 ~ PATTERN {
rec = $1 OFS $2 OFS $4 OFS $7
for (i=9; i<=NF; i++) {
rec = rec OFS $i
if ($i ~ SEARCH) {
break
}
}
print rec
}
' "$FILE_LOCATION"
}
OUTFILE="$MYPATH$NAME_OF_FILE$DATE.$FILE_EXT"
printFmt "$STORED_PROCS_FINISHED" "[01]" >> "$OUTFILE"
…7 other calls to printFmt each with I/O redirection…
Or even:
{
printFmt "$STORED_PROCS_FINISHED" "[01]"
…7 other calls to printFmt…
} >> "$OUTFILE"
On the whole, I'd probably pass the file(s) to be scanned as an argument to the function too:
printFmt() {
pattern="${1:?}"
search="${2:?}"
shift 2
awk -v PATTERN="$pattern1" -v SEARCH="$search" '
$0 ~ PATTERN {
rec = $1 OFS $2 OFS $4 OFS $7
for (i=9; i<=NF; i++) {
rec = rec OFS $i
if ($i ~ SEARCH) {
break
}
}
print rec
}
' "$#" # All the remaining arguments
}
{
printFmt "$STORED_PROCS_FINISHED" "[01]" "$FILE_LOCATION"
…7 other calls to printFmt…
} >> "$OUTFILE"
This gives the most flexibility about where the data comes from and goes to. It allows the function to read its standard input if no file name arguments are supplied. The ${1:?} notation will generate an error if $1 is not set to a non-empty string; it is a crude but effective way of checking that argument 1 (the pattern) was provided to the function. Similarly with the search argument too. The error message won't be wonderfully informative, but any message is probably better than trying to proceed when the values were not provided.