Is equality properly defined on chan? - clojure

Question

I want to maintain a collection of channels, with the ability to add and remove channels. Is the equality defined so I can conj and disj correctly?
In other words, will this always work?
=> (def chan-collection (atom #{}))
=> (def my-chan-1 (chan))
=> (def my-chan-2 (chan))
=> #chan-collection
#{}
=> (swap! chan-collection conj my-chan-1)
=> #chan-collection
#{#<ManyToManyChannel clojure.core.async.impl.channels.ManyToManyChannel#6ec3a2f6>}
=> (swap! chan-collection conj my-chan-2)
=> #chan-collection
#{#<ManyToManyChannel clojure.core.async.impl.channels.ManyToManyChannel#382830a1>
#<ManyToManyChannel clojure.core.async.impl.channels.ManyToManyChannel#6ec3a2f6>}
=> (swap! chan-collection disj my-chan-1)
=> #chan-collection
#{#<ManyToManyChannel clojure.core.async.impl.channels.ManyToManyChannel#382830a1>}
=> (swap! chan-collection disj my-chan-2)
=> #chan-collection
#{}

Answer 1

Yes this is true, and changing it would break everything.
Channels are identical? if they are the same chan object, and therefore are equal in all cases. All other comparisons of chans are explicitly not equal, and this is good for you. You want removal to remove the exact chan you ask to be removed rather than some equivalent chan with the same contents. So it's fortunate that chans that are not identical are also not equal
user> (= (chan) (chan))
false
user> (identical? (chan) (chan))
false
user> (identical? my-chan-1 (chan))
false
user> (identical? my-chan-1 my-chan-1)
true
user>
user> (= my-chan-1 my-chan-1)
true
In the general "Clojure world" this same property is true of all things that are Identities rather than values. Identities have values that change over time so it doesn't make sense to say that two identities are equal if they happen to contain the same value at the moment you ask, even though this may only be true for you and never for anyone else. comparing the values in identities makes much more sense. for example like chans, atoms with the same values are also not equal and this is a fundamental property of clojure that will never change.
user> (let [a (atom 1)]
(= a a))
true
user> (= (atom 1) (atom 1))
false
Provided you want to remove them by giving the exact chan you want removed as an argument to disj, as you are doing above, rather than some other notion like "remove the channel with 42 in it"
If we do the same setup:
user> (require '[clojure.core.async :refer [<! <!! >! chan]])
nil
user> (def chan-collection (atom #{}))
#'user/chan-collection
user> (def my-chan-1 (chan))
#'user/my-chan-1
user> (def my-chan-2 (chan))
#'user/my-chan-2
user> (swap! chan-collection conj my-chan-1 my-chan-2)
#{#object[clojure.core.async.impl.channels.ManyToManyChannel 0x35b61c71 "clojure.core.async.impl.channels.ManyToManyChannel#35b61c71"] #object[clojure.core.async.impl.channels.ManyToManyChannel 0x240e86d5 "clojure.core.async.impl.channels.ManyToManyChannel#240e86d5"]}
and then ask to have "the empty chan" removed:
user> (swap! chan-collection disj (chan))
#{#object[clojure.core.async.impl.channels.ManyToManyChannel 0x35b61c71 "clojure.core.async.impl.channels.ManyToManyChannel#35b61c71"] #object[clojure.core.async.impl.channels.ManyToManyChannel 0x240e86d5 "clojure.core.async.impl.channels.ManyToManyChannel#240e86d5"]}
we can verify that it does nothing.