Remove everything else from the String using regular expression - regex

Question

I have this regular expression which is what is allowed in the String.
^\pL*['#-]?\pL*\$
The requirements have changed and now I need to drop everything else from the String. For example only one of these special characters ', #, and - is allowed.
How can I change this regex to drop everything else that does not fit this ?
Here is the list of expected values:
JohnO'Connell -> allowed. should be as is.
JohnDias -> allowed. should be as is.
JohnOConnell' -> allowed. should be as is.
JohnOConnell# -> allowed. should be as is.
JohnOConnell- -> allowed. should be as is.
JohnOConnell-# -> should return JohnOConnell-
JohnOConn34ell -> should return JohnOConnell
*JohnOConnell -> should return JohnOConnell
JohnOConnell* -> should return JohnOConnell
JohnOConn$%ell -> should return JohnOConnell
Thanks

Answer 1

If I understand it correctly, you could do it this way:
// Test data
def tests = [ [ input:"JohnO'Connell", output:"JohnO'Connell" ],
[ input:"JohnDias", output:"JohnDias" ],
[ input:"JohnOConnell'", output:"JohnOConnell'" ],
[ input:"JohnOConnell#", output:"JohnOConnell#" ],
[ input:"JohnOConnell-", output:"JohnOConnell-" ],
[ input:"JohnOConnell-#", output:"JohnOConnell-" ],
[ input:"JohnOConn34ell", output:"JohnOConnell" ],
[ input:"*JohnOConnell", output:"JohnOConnell" ],
[ input:"JohnOConnell*", output:"JohnOConnell" ],
[ input:"JohnOConn\$%ell", output:"JohnOConnell" ] ]
String normalize( String input ) {
int idx = 0
input.replaceAll( /[^A-Za-z'#\-]/, '' ) // remove all disallowed chars
.replaceAll( /['#\-]/ ) { match -> // replace 2nd+ instance of special chars
idx++ == 0 ? match : ''
}
}
tests.each {
assert normalize( it.input ) == it.output
}