Find Multiple Occurrences in String using REFind - coldfusion

Question

I'm trying to get ColdFusion's REFindNoCase function to return multiple instances of a matching string but can't seem to get it to work:
<cfset string2test="cfid skldfjskdl cfid sdlkfjslfjs cftoken dslkfjdslfjks cftoken">
<cfset CookieCheck = REFindNoCase( 'CFTOKEN', string2test, 1, true)>
<cfif arrayLen( CookieCheck['LEN'] ) gt 1>
MULTIPLE CFTOKEN!
</cfif>
Is there a regular expression magic syntax I need to use to make it search for more than 1?

Answer 1

The syntax of the code above will create structure with arrays (LEN,POS) for pattern match and subexpressions. RegEx subexpressions are within parenthesis in the pattern. The 'CFTOKEN' pattern does not contain a subexpression.
I don't think that REFindNoCase will do what you are wanting to accomplish.
For example, if you use '.*?(cftoken)' as the pattern:
<cfset CookieCheck = REFindNoCase('.*?(CFTOKEN)', string2test, 1, true)>
(CFTOKEN) is a subexpression. If you remove the "?", the information for the last occurrence of 'cftoken' is returned.
The values in the first array items will match the entire pattern up to the first 'cftoken' (the first 40 characters of the string). The second set of values will identify the 'cftoken' string that was found in first match (first 40 chars).
Because the statement in the example does not include subexpressions, only the first pattern match is returned.
If you need to check to see if something is listed multiple times or you don't need to manipulate the original string, I would recommend using REMatchNoCase(). It returns an array of pattern matches but without the position info.

Answer 2

You could create a custom method to loop over the string, and toss each occurrence into an array (or struct, or whatever you want). Here's an example of how I might approach it:
<cfscript>
public array function reFindMatches(required string regex, required string str) {
var start = 1;
var result = [];
var matches = [];
var match = '';
do {
matches = ReFind(arguments.regex, arguments.str, start, true);
if ( matches.pos[1] ) {
match = matches.len[1] ? Mid(arguments.str, matches.pos[1], matches.len[1]) : '';
ArrayAppend(result, match);
start = matches.pos[1] + matches.len[1];
}
} while(matches.pos[1]);
return result;
}
testString = 'cfid skldfjskdl cfid sdlkfjslfjs cftoken dslkfjdslfjks cftoken';
regex = '(?i)(\bcftoken\b)';
check = reFindMatches(regex=regex, str=testString);
WriteDump(var=check);
</cfscript>
The sample regex I've included begins with (?i) which indicates that the search is case insensitive. So, it's not necessary to call ReFindNoCase ... you can simply pass in whatever regex you wish to use.
The code above should output an array with two elements containing the word cftoken.

Answer 3

If you need to count how many instances there are, use rematch (or rematchNoCase).
If all you need is to identify if there's more than one, you can do this:
<cfset FirstInstance = refindNoCase( 'cftoken' , string2test ) />
<cfif FirstInstance AND refindNoCase( 'cftoken' , string2test , FirstInstance+7 ) >
... more than one instance ...
</cfif>
Which is probably more efficient than rematch, using sub-expressions or looping multiple times.
Depending on the data concerned, it might be even more efficient to do something like:
<bfif string2text.indexOf('cftoken') NEQ string2text.lastIndexOf('cftoken') >
(i.e. if you know that an additional instances would always near the end of the string, whilst initial ones are not.)