XSLT transformations based on configuration file - xslt

Question

Input:
<chapter xmlns='http://www.w3.org/1998/Math/MathML'>
<math>
<mtext mathcolor="#3e9a3c">This is sample 1</mtext>
<mtext mathcolor="#009bd2">This is sample 2</mtext>
</math>
</chapter>
Output:
<?xml version='1.0' encoding='UTF-8' ?>
<chapter xmlns="http://www.w3.org/1998/Math/MathML"><math>~COLOR~[Green]This is sample 1~COLOR~[Red]This is sample 2</math></chapter>
Configuration file:
<?xml version="1.0"?>
<colors>
<color><mathcolor>#3e9a3c</mathcolor><textcolor>Green</textcolor><colorvalue>1</colorvalue></color>
<color><mathcolor>#009bd2</mathcolor><textcolor>Red</textcolor><colorvalue>2</colorvalue></color>
</colors>
XSLT tried:
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:m="http://www.w3.org/1998/Math/MathML" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.w3.org/1998/Math/MathML" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:mml="http://www.w3.org/1998/Math/MathML">
<xsl:output method="xml" encoding="UTF-8" indent="no"/>
<xsl:strip-space elements="*"/>
<xsl:template match="#* | node()">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="m:mtext">
<xsl:if test="#mathcolor">
<xsl:choose>
<xsl:when test="#mathcolor='#3e9a3c'"><xsl:text disable-output-escaping="yes">~COLOR~[Green]</xsl:text></xsl:when>
<xsl:when test="#mathcolor='#009bd2'"><xsl:text disable-output-escaping="yes">~COLOR~[Red]</xsl:text></xsl:when>
</xsl:choose>
</xsl:if>
<xsl:apply-templates/></xsl:template>
</xsl:stylesheet>
I am in need to transform the Input given above to the required output based on the configuration file. If the user updates the configuration file, and if the Input has mathcolor attribute value, then its corresponding color should be transformed as shown in output. I can able to use XSLT 1.0. Kindly help to solve this issue
For example:
If the user adds the below coding in the configuration file:
<color><mathcolor>#007c62</mathcolor><textcolor>Magenta</textcolor><colorvalue>3</colorvalue></color> and Input contains mathcolor="#007c62", then Magenta should be applied in the output.

Answer 1

This should work:
Stylesheet
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:m="http://www.w3.org/1998/Math/MathML"
xmlns:mml="http://www.w3.org/1998/Math/MathML"
xmlns:xlink="http://www.w3.org/1999/xlink"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns="http://www.w3.org/1998/Math/MathML">
<xsl:output method="xml" encoding="UTF-8" indent="no"/>
<xsl:strip-space elements="*"/>
<!--
Config file name/path, can be passed as a parameter to XSL transformation
-->
<xsl:param name="config.file" select="'config.xml'"/>
<xsl:template match="#* | node()">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
</xsl:copy>
</xsl:template>
<!-- <m:mtext> elements with a #mathcolor attribute, no need for <xsl:if> -->
<xsl:template match="m:mtext[#mathcolor]">
<xsl:text>~COLOR~[</xsl:text>
<!--
Fetch color name from $config.file (<color> element with a <mathcolor>
child that has the same value as the #mathcolor attribute of the element
currently being processed)
-->
<xsl:value-of
select="document($config.file)/colors/color
[mathcolor = current()/#mathcolor]/textcolor"/>
<xsl:text>]</xsl:text>
<xsl:apply-templates/>
</xsl:template>
</xsl:stylesheet>
Input
<chapter xmlns='http://www.w3.org/1998/Math/MathML'>
<math>
<mtext mathcolor="#3e9a3c">This is sample 1</mtext>
<mtext mathcolor="#009bd2">This is sample 2</mtext>
</math>
</chapter>
config.xml
<?xml version="1.0"?>
<colors>
<color>
<mathcolor>#3e9a3c</mathcolor>
<textcolor>Green</textcolor>
<colorvalue>1</colorvalue>
</color>
<color>
<mathcolor>#009bd2</mathcolor>
<textcolor>Red</textcolor>
<colorvalue>2</colorvalue>
</color>
</colors>
Output
<?xml version="1.0" encoding="UTF-8"?>
<chapter xmlns="http://www.w3.org/1998/Math/MathML">
<math>~COLOR~[Green]This is sample 1~COLOR~[Red]This is sample 2</math>
</chapter>