What to create? a function or template or? - xslt

Question

I've the following problem see the code example:
<xsl:if test="/Document/test/id">
<TEST1>
<xsl:value-of select="/Document/test/id"/>
</TEST1>
</xsl:if>
I've a huge xslt script with a lot of same code. I wanted to create a function but I got all the time errors. I was asking myself if that is the right solution to solve this problem.
To make the code better maintainable I want to use something like the following.
This is not xslt syntax because I don't know how, but to give an idea what I'm looking for.
...
<xsl:something "TEST1", "/Document/test/id1" />
<xsl:something "TEST2", "/Document/test/id2" />
...
The code would be better readable and maintainable, although I don't know how to solve this :-(
Any advise is welcome...
Regards Dirk

Answer 1

This transformation:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:variable name="vDoc" select="/"/>
<xsl:template match="/">
<xsl:sequence select="my:test(xs:QName('Test1'), /*/test/id1/string())"/>
<xsl:sequence select="my:test(xs:QName('Test2'), /*/test/id2/string())"/>
<xsl:sequence select="my:test(xs:QName('Test3'), /*/test/id3/string())"/>
<xsl:sequence select="my:test(xs:QName('Test4'), /*/test/id4/string())"/>
</xsl:template>
<xsl:function name="my:test">
<xsl:param name="pName" as="xs:QName"/>
<xsl:param name="pToPresent" as="item()?"/>
<xsl:if test="$pToPresent">
<xsl:element name="{$pName}">
<xsl:sequence select="$pToPresent"/>
</xsl:element>
</xsl:if>
</xsl:function>
</xsl:stylesheet>
When applied on the following XML document:
<Document>
<test>
<id1>Some Id1</id1>
</test>
<test>
<id2>Some Id2</id2>
</test>
<test>
<id4>Some Id4</id4>
</test>
</Document>
the wanted, correct result is produced:
<Test1>Some Id1</Test1>
<Test2>Some Id2</Test2>
<Test4>Some Id4</Test4>
Do note:
The first argument of my:test() is declared of type xs:QName, which guarantees that the value of the name attribute of the xsl:element instruction is always a valid name.
The second argument of my:test() is declared very loosely of type item()?, which gives us the freedom to provide any type of item (string or node or element, or ...) and that exactly what is provided would be reproduced "as is".

Answer 2

I think this is the closest to what you are going for:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="custom-functions" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/">
<CONTENT>
<xsl:sequence select="f:rename('TEST1', /Document/test/id1)"/>
<xsl:sequence select="f:rename('TEST2', /Document/test/id2)"/>
</CONTENT>
</xsl:template>
<xsl:function name="f:rename">
<xsl:param name="name" as="xs:string"/>
<xsl:param name="toWrap" />
<xsl:if test="$toWrap">
<xsl:element name="{$name}">
<xsl:value-of select="$toWrap"/>
</xsl:element>
</xsl:if>
</xsl:function>
</xsl:stylesheet>
When this is run on the following input:
<Document>
<test>
<id1>Hello!</id1>
<id2>Hello again!</id2>
</test>
</Document>
The output produced is:
<CONTENT>
<TEST1>Hello!</TEST1>
<TEST2>Hello again!</TEST2>
</CONTENT>
You could also try this, which is a little more verbose, but XSLT 1.0 compatible:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/">
<CONTENT>
<xsl:apply-templates select="/Document/test/id1" mode="rename">
<xsl:with-param name="name" select="'TEST1'" />
</xsl:apply-templates>
<xsl:apply-templates select="/Document/test/id2" mode="rename">
<xsl:with-param name="name" select="'TEST2'" />
</xsl:apply-templates>
</CONTENT>
</xsl:template>
<xsl:template match="#* | node()" mode="rename">
<xsl:param name="name" />
<xsl:element name="{$name}">
<xsl:value-of select="." />
</xsl:element>
</xsl:template>
</xsl:stylesheet>
When run on the above sample XML, again the same output is produced.