Faking a variable in an Xpath expression - xslt

Question

In straight XSLT 1.0, it's not possible to use a string variable as an XPath expression.
But if the possible expressions were all simple, like "/book/chapter/verse" or "/year/make/model/style" -- only children axis, just element nodes, no predicates -- is it possible to build a key where the key string is that path? Something like
<xsl:key name="elementByPath" match="*" use="path()" />
If so, then you could have
select=key(elementByPath, $var)
where $var could be a string like "/book/chapter/verse".
But straight XSLT 1.0 doesn't have a path() function. :(
It's easy enough to get a path with
<xsl:for-each select="ancestor-or-self::*">
<xsl:text>/</xsl:text>
<xsl:value-of select="name()"/>
</xsl:for-each>
but that can't go in the #use of a key. :(
Is there another way to select elements by a variable XPath expression when the possible expressions (though many) are simple?

Answer 1

Something can be done:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="pPath1" select="'/books/book/title'"/>
<xsl:param name="pPath2" select="'/books/book/description'"/>
<xsl:key name="kElemByPath" match="*"
use="concat('/', name(ancestor-or-self::*[last()])
,'/', name(ancestor-or-self::*[last()-1])
,'/', name(ancestor-or-self::*[last()-2])
)"/>
<xsl:template match="/">
<xsl:copy-of select="key('kElemByPath', $pPath1)"/>
==========
<xsl:text/>
<xsl:copy-of select="key('kElemByPath', $pPath2)"/>
</xsl:template>
</xsl:stylesheet>
When this transformation is applied on the following XML document:
<books>
<book isbn="1590593049">
<title>Extending Flash MX 2004</title>
<description>
Using javascript alongwith actionscript 3.0 and mxml.</description>
</book>
<book isbn="0132149184">
<title>Java Software Solutions</title>
<description>
Complete book full of case studies on business solutions and design concepts while building mission critical
business applications.
</description>
</book>
</books>
the wanted, correct result is produced:
<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
Using javascript alongwith actionscript 3.0 and mxml.</description>
<description>
Complete book full of case studies on business solutions and design concepts while building mission critical
business applications.
</description>
If you know the maximum number of location steps in a "path", then you can define a key similar to this example. The expressions with smaller number of location steps must end with the necessary number of slashes.

Answer 2

Or how about just recursively parsing the string brute-force:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="pPath1" select="'books/book/title'"/>
<xsl:param name="pPath2" select="'books/book/description'"/>
<xsl:template match="/">
<xsl:call-template name="elementsByPath">
<xsl:with-param name="path" select="$pPath1" />
</xsl:call-template>
<xsl:text>==========
</xsl:text>
<xsl:call-template name="elementsByPath">
<xsl:with-param name="path" select="$pPath2" />
</xsl:call-template>
</xsl:template>
<xsl:template name="elementsByPath">
<xsl:param name="path" />
<xsl:choose>
<xsl:when test="contains($path,'/')">
<xsl:for-each select="*[name()=substring-before($path,'/')]">
<xsl:call-template name="elementsByPath">
<xsl:with-param name="path" select="substring-after($path,'/')" />
</xsl:call-template>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="*[name()=$path]" />
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="*">
<xsl:copy-of select="." /><xsl:text>
</xsl:text>
</xsl:template>
</xsl:stylesheet>
When that transformation is applied to Dimitre's sample XML, the correct result is obtained:
<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
Using javascript alongwith actionscript 3.0 and mxml.
</description>
<description>
Complete book full of case studies on business solutions and design concepts while building mission critical
business applications.
</description>
I think that would work . . .