Replace variables values between two files using VBS - regex

Question

I'm dealing with a script and I won't be able to create it without your help.
This is what I need: I have two .txt files, one contains variables (between two #) like these:
#PickupFolder#=E:/SonicDataFiles/AR_INT/GPP_VE/IN
#Db1Url#=jdbc:sonic:sqlserver://CARASETMS:1433;databaseName=CRM
The other .txt have variables that need to be completed from the previous file
#Db1Url#=
#Db1Pwd#=
I need to get every variable in the first file (I guess I have to use regular expression) and replace its value in the second file if the variable exits.
I would really appreciate if anyone has a similar script to get an idea. I'm trying to do it with VBS.
Thanks a lot.
Gerardo.
Buenos Aires, Argentina.
This was my original script:
'ReplaceScript "c:\Variables_INT.txt" "C:\AR_INT.tailoring.properties"
'DEFINE CONSTANTS
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8
'DEFINE VARIABLES
strTxtFile = Wscript.Arguments(0)
strTailoringFile = Wscript.Arguments(1)
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set WshShl = WScript.CreateObject("WScript.Shell")
Set objFileVariablesTXT = objFSO.OpenTextFile (strTxtFile, ForReading) 'Variables_INT.txt
Set objFileTailoring = objFSO.OpenTextFile (strTailoringFile, ForReading) 'AR_INT.tailoring.properties
Dim strQuartz, strPickupfFolder, strUrl, strDbPwd, strDbUser, strDbDestTable
strSearchString = objFileVariablesTXT.ReadAll
'SEARCH THE FILE FOR THE NEEDED DATA
vQuartz = InStr(strSearchString, "#QuartzJars#=")
vPickupFolder = InStr(strSearchString, "#PickupFolder#=")
vDbUrl = InStr(strSearchString, "#Db1Url#=")
vDbPwd = InStr(strSearchString, "#Db1Pwd#=")
vDbUser = InStr(strSearchString, "#Db1User#=")
vDbDestTable = InStr(strSearchString, "#DestinationTable#=")
'PARSE OUT THE NEEDED INFO
If vQuartz <> 0 Then
'vQuartz = vQuartz + 13
strQuartz = Mid(strSearchString, vQuartz, 304)
' WScript.Echo strQuartz
End If
If vPickupFolder <> 0 Then
'vPickupFolder = vPickupFolder + 15
strPickupfFolder = Mid(strSearchString, vPickupFolder, 50)
' WScript.Echo strPickupfFolder
End If
If vDbUrl <> 0 Then
'vDbUrl = vDbUrl + 9
strUrl = Mid(strSearchString, vDbUrl, 65)
' WScript.Echo strUrl
End If
If vDbPwd <> 0 Then
'vDbPwd = vDbPwd + 9
strDbPwd = Mid(strSearchString, vDbPwd, 17)
'WScript.Echo strDbPwd
End If
If vDbUser <> 0 Then
'vDbUser = vDbUser + 10
strDbUser = Mid(strSearchString, vDbUser, 25)
'WScript.Echo strDbUser
End If
If vDbDestTable <> 0 Then
'vDbDestTable = vDbDestTable + 19
strDbDestTable = Mid(strSearchString, vDbDestTable, 29)
'WScript.Echo strDbDestTable
End If
objFileVariablesTXT.Close
strReplaceString = objFileTailoring.ReadAll
arrReplacements = Array("#QuartzJars#=Ç" & strQuartz , "#PickupFolder#=Ç" & strPickupfFolder, "#Db1Url#=Ç" & strUrl, "#Db1Pwd#=Ç" & strDbPwd, "#Db1User#=Ç" &strDbUser, "#DestinationTable#=Ç" & strDbDestTable)
objFileTailoring.Close
Set objFileTailoring = Nothing
For Each strReplacement In arrReplacements
strReplaceWhat = Split(strReplacement, "Ç")(0)
'WScript.Echo strReplaceWhat
strReplaceWith = Split(strReplacement, "Ç")(1)
'WScript.Echo strReplaceWith
strReplaceString = Replace(strReplaceString, strReplaceWhat, strReplaceWith)
Next
'wScript.Echo strReplaceString
Set objFileTailoring = objFSO.OpenTextFile(strTailoringFile, 2, true)
objFileTailoring.Write strReplaceString
objFileTailoring.Close

Answer 1

Quick and Dirty:
Dim sFSpec1 : sFSpec1 = "..\data\frs.txt"
Dim sFSpec2 : sFSpec2 = "..\data\sec.txt"
Dim dicRpl : Set dicRpl = CreateObject( "Scripting.Dictionary" )
Dim reCut : Set reCut = New RegExp
reCut.Global = True
reCut.Pattern = "(#[^#]+#)\s*=\s*(.*?)\s*$"
Dim sAll : sAll = goFS.OpenTextFile( sFSpec1 ).ReadAll
WScript.Echo sAll
WScript.Echo "---------------"
Dim oMTS : Set oMTS = reCut.Execute( sAll )
Dim oMT
For Each oMT In oMTS
dicRpl( oMT.SubMatches( 0 ) ) = oMT.SubMatches( 1 )
Next
sAll = goFS.OpenTextFile( sFSpec2 ).ReadAll
WScript.Echo sAll
WScript.Echo "---------------"
Dim sKey
For Each sKey In dicRpl.Keys
sAll = Replace( sAll, sKey, dicRpl( sKey ) )
Next
WScript.Echo sAll
output:
#PickupFolder#=E:/SonicDataFiles/AR_INT/GPP_VE/IN
#Db1Url#=jdbc:sonic:sqlserver://CARASETMS:1433;databaseName=CRM
---------------
#Db1Url#=
#Db1Pwd#=
---------------
jdbc:sonic:sqlserver://CARASETMS:1433;databaseName=CRM=
#Db1Pwd#=
If that solves your problem in principle, we can nail down details.
ADDED:
As Jean-François Corbett surely is right, use the pattern
reCut.Pattern = "(#[^#]+#=)(.*?)\s*$"
and the final replacement
sAll = Replace( sAll, sKey, sKey & dicRpl( sKey ) )
This version assumes a strict #x#=[y] format in both files.

Answer 2

Tested this brute force approach, it works for me...
Dim FSO, txs, all, sourceLines, i, targetLines, j, delimiterPosition
Set FSO = CreateObject("Scripting.FileSystemObject")
set txs = FSO.OpenTextFile(".\source.txt", 1)
all=txs.ReadAll
txs.Close
sourceLines=Split(all,vbCrLf)
set txs = FSO.OpenTextFile(".\target.txt", 1)
all=txs.ReadAll
txs.Close
targetLines=Split(all,vbCrLf)
for i = 0 to ubound(sourceLines)
If sourceLines(i)<>"" Then
delimiterPosition = InStr(2, sourceLines(i), "#")
sourceVarName = Mid(sourceLines(i), 2, delimiterPosition - 2)
sourceVarValue = Mid(sourceLines(i), delimiterPosition + 2)
for j = 0 to ubound(targetLines)
If targetLines(j)<>"" Then
delimiterPosition = InStr(2, targetLines(j), "#")
targetVarName = Mid(targetLines(j), 2, delimiterPosition - 2)
If targetVarName = sourceVarName Then
targetLines(j) = targetLines(j) & sourceVarValue
End If
End If
next
End If
next
set txs = FSO.OpenTextFile(".\target.txt", 2)
for j = 0 to ubound(targetLines)
txs.WriteLine targetLines(j)
next
txs.Close
Target file is now:
#Db1Url#=jdbc:sonic:sqlserver://CARASETMS:1433;databaseName=CRM
#Db1Pwd#=