Edit Floating Specific Point Field Preserving/Padding w/ Whitespace in AWK? - regex

Question

I have a file with the line:
CH1 12.30 4.800 12 !
I want to replace a specific field ... say $2 with some equivalent scaled by chosen floating point scalar on [0.0,1.0). However, I want to keep the same number of decimal digits and further to pad the front end with spaces to maintain the original length.
I'm thinking some combination len/gsub/printf in awk could accomplish this.
As an example of what I have tried currently:
scalar=0.00; echo 'CH1 12.30 4.800 12 !' | awk -v sc=$scalar '/CH1/{gsub(/[0-9]*\.[0-9]*/,$2*sc,$2);} {print;}'
Output:
CH1 0 4.800 12 !
Output:
Correctly outputs scaled #, but spaces are stripped from not just field $2, but entire line.
scalar=0.00; echo 'CH1 12.30 4.800 12 !' | awk -v sc=$scalar '/CH1/{gsub(/$2/,$2*sc,$0);} {print;}'
Output:
CH1 12.30 4.800 12 !
Notes:
Does nothing! Output is unchanged.
Assumptions:
Fields $2 and $3 may be the same, but I ONLY want to change field $2.
Field $1 contains only alphanumeric characters.
Fields $2 and $3 are floating point numbers with an arbitrary # of decimal digits, typically with the # of digits being on the range [1,4]. The whole part has no more than 3 digits..
Field $4 is an integer on the range [8,99].
Anything after field $4 is a comment and may contain special characters.
Searching for similar questions I've come across some questions pertaining to whitespace preservation, and those having given me some ideas... but mine is a bit different because I actually want to add whitespace, to keep the decimal place effectively locked in the same spot on the line, to keep user formatting nice in the targeted file.

Answer 1

The gsub(/$2/,...) expressions fail because /$2/ is looking for a literal $2 string, as opposed to whatever is in field 2. (And gsub is overkill since we are only changing one instance, so plain sub suffices, but gsub is harmless here.)
We can use just $2 (without slashes, although it's going to be treated as a regular expression rather than a literal string):
$ scalar=0.00; echo 'CH1 12.30 4.800 12 !' |
awk -v sc=$scalar '/CH1/{gsub($2,$2*sc);} {print;}'
CH1 0 4.800 12 !
This loses the decimal place stuff too, so is still not quite what we want, but shows that your approach can work.
Given that sprintf() can produce a string according to a format directive like "%5.2f" (which is what we would want to get 12.30), all we need to do is figure out the total length of the field $2 and the length of the fractional part (after the .), which is easy using split and length. Constructing the replacement string is even easier than it might first look, because instead of a literal 5 and 2, we can use * to extract integer arguments. Hence:
$ cat foo.sh
#! /bin/sh
scalar=0.00
echo 'CH1 12.30 4.800 12 !'
echo 'CH1 12.30 4.800 12 !' |
awk -v sc=$scalar '
$2 ~ /[0-9]*\.[0-9]*/ {
split($2, parts, /\./)
ofraclen = length(parts[2])
repl = sprintf("%*.*f", length($2), ofraclen, $2 * sc)
sub(/[0-9]*\.[0-9]*/, repl)
}
{print}
'
$ sh foo.sh
CH1 12.30 4.800 12 !
CH1 0.00 4.800 12 !
I put in the extra echo so that we can see that the fields still line up. I changed the matching criteria to $2 ~ ... so that we are guaranteed that $2 will split properly. We split it into its integer and fractional parts, grab the length of the fractional part, produce the replacement string, and then use sub on the (first) occurrence of a floating point number (safe if and only if field $1 never matches, there's no test for $1 matching and if so we'll sub the wrong one).
(I actually like the semicolons after each statement, but I took them all out here since they're not strictly required. Also, most of the temporary variables can be eliminated, keeping just parts, but the result will be difficult to understand.)

Answer 2

This is a general approach to reproducing the padding from the input in the output after operating on some field(s):
$ cat tst.awk
NR==1 {
# Find the width of each space-padded, right-aligned field:
rec = $0
for (i=1; i<=NF; i++) {
match(rec,/[^[:space:]]+/)
w[i] = RSTART - 1 + RLENGTH
rec = substr(rec,w[i]+1)
}
# Find the precision of the target field:
match($2,/\..*/)
p = RLENGTH - 1
}
{
# print the original just for comparison
print
# do the math:
$2 = sprintf("%.*f", p, $2 * scalar)
# print the updated record:
for (i=1;i<=NF;i++) {
printf "%*s", w[i], $i
}
print ""
}
.
$ awk -v scalar=0 -f tst.awk file
CH1 12.30 4.800 12 !
CH1 0.00 4.800 12 !
$ awk -v scalar=0.5 -f tst.awk file
CH1 12.30 4.800 12 !
CH1 6.15 4.800 12 !
$ awk -v scalar=9 -f tst.awk file
CH1 12.30 4.800 12 !
CH1 110.70 4.800 12 !
The above will work no matter what the value of scalar or which floating point field you want to change (easy tweak to work for decimal fields too if desired) and no matter what the value of $1.